Microsoft Excel - How often do you use it?

[Coach]

For advanced users, tell us some of your tricks in terms of using the formulas and such.

For beginners, ask questions here, hopefully answers could be provided.

As for me, my question to the experts/advanced users,

Let's say if I have a spreadsheet with column A that has names, typically last name, first name and middle initial (example: Smith, Joe Steve). Column B has names that is typically the same as column A, except it would be missing the middle name or a misspelling on the first name (example: Smith, Joe).


Column A would have say 450 names and Column B would have 150. How can a "near" match search be found, after utilizing the conditional formatting that highlights duplicate values?

[Coach]

Originally Posted by kccrow

Let me see if I can put something together that will explain all the formulas. Also, I think you did not alter the formula when you inserted column D as I had outlined, which is why you're getting that particular outcome.

Done, and much appreciated it.

[Fish]

CONCATENATE! CONCATENATE! CONCATENATE!!!

[suzzer99]

[kccrow]

Noticed some minor errors on both of our parts and fixed up your worksheet Coach. Sent it back to you.

Posting here just for others to note the changes.
Assuming format of cells as displayed in picture, here are the formulas

Cell B2:
=IF(A2="","",IFERROR(CONCATENATE(TEXT(LEFT(A2,FIND(",",A2)-1),""),", ",TEXT(LEFT(MID(A2,FIND(" ",A2)+1,3),1),"")),""))

Cell C2:
=IF(A2="","",IF(IFERROR(MATCH(B2,F:F,0),0)>0,"On Roster","Not On Roster"))

Cell D2:
=IF(A2="","",IFERROR(ADDRESS(MATCH($B2,$F:$F,0),5),"No Reference"))

Cell F2:
=IF(E2="","",IFERROR(CONCATENATE(TEXT(LEFT(E2,FIND(",",E2)-1),""),", ",TEXT(LEFT(MID(E2,FIND(" ",E2)+1,3),1),"")),""))

Conditional Format 1:
=$C1="On Roster"
Applies to: $B:$B

Conditional Format 2:
=AND(LEN(INDEX($B:$B,MATCH($F1,$B:$B,0)))>0,$F1<>"Short Name")=TRUE
Applies to: $F:$F

Image:



I'll write up a little tutorial for you on what all of that is doing tomorrow night.

[Mosbonian]

Originally Posted by Fish

CONCATENATE! CONCATENATE! CONCATENATE!!!

Whenever I am doing an interview with a prospective new associate I ask them to rate their Excel skills.....so many times they say Advanced or Intermediate.

I have an Excel model we use to test their skill set when they advance to the next round of interviews. You can tell their real level of skill set when you ask them to Concatenate....most freeze up or panic.

[Garcia Bronco]

Everyday. vlookup is a good formula to do list comparisons. Sometimes it's difficult to figure out. I recommend playing around with it with some kind of stupid list. You'll have to Google it or use the help for instructions. They can be a bit of a logical problem. But if you want it take common things out of two lists... It's a good tool.

[kccrow]

Originally Posted by Garcia Bronco

Everyday. vlookup is a good formula to do list comparisons. Sometimes it's difficult to figure out. I recommend playing around with it with some kind of stupid list. You'll have to Google it or use the help for instructions. They can be a bit of a logical problem. But if you want it take common things out of two lists... It's a good tool.

Two considerations on VLOOKUP vs INDEX(MATCH...

VLOOKUP requires alot of processing power because it evaluates an entire table at once, which is why some workbooks with large data sets seem to take forever to populate a change. VLOOKUP cannot look left of the lookup value. Adding and deleting columns in VLOOKUP also, often, breaks formulas because of the static nature of calling the number of columns to the right to look for. You have to change the formula from VLOOKUP to HLOOKUP to handle vertical and horizontal matching.

INDEX and MATCH have a bit more flexibility and require significantly less processing power because it evaluates a cell reference rather than an entire table. INDEX/MATCH can look anywhere on a sheet: left, right, up, and down. INDEX/MATCH rarely uses static values unless you explicitly tell it to. Most often there is no need to have a static reference value, which means you can add and delete columns and rows with no effect on the outcome, providing you set up the formulas appropriately.

Basically, VLOOKUP is a nice beginner's tool but if you want to do more and get more out of Excel, then learning to use other functions like INDEX, MATCH, LEFT, LEN, ADDRESS, INDIRECT and so forth are going to make your life MUCH easier and more rewarding. Those functions used in conjunction with one another make Excel versatile and allows you to use it like a database. Most beginners struggle with logic though, so keeping the formulas straight and knowing what they are doing is extremely important.

Yes, you could just as easily set up an SQL database with two tables for the names and use an INNER JOIN function to return a list of matches or a LEFT/RIGHT JOIN to return one of the lists entirely and all the matches in the other list. It wouldn't be terrible at all to set up, especially if you can code an HTML UI parsing an INSERT INTO function, but most people that are working with Excel don't also use or know SQL. Even then you're going to have to end up with adding some more complex statements using wildcards and such given the parameters Coach outlined because the data sets don't exactly match. Anyhow, pick one, learn one, and then move on from there. For the vast majority of people, learning Excel will be much more valuable in day-to-day business.

[kccrow]

So, as promised, I'll break things down. I've put this in spoilers because if you have a need/want to learn this shit then I give you the option to read on and open up what is a rather lengthy document. If you don't have the need, it's easy to ignore because everything is collapsed down.

Spoiler!

First, let's discuss the inherent formulas by backing them out. Not that all functions that I state initially, I'm telling you how Excel shows the function and anything inside brackets is an optional value.

FIND(find_text,within_text,[start_num]): The FIND function returns the starting position of one text string within another text string. Much of the time, you'll end up looking for a a starting point within a text string when you actually put it into practice.

How I used it: FIND(" ",A2)
Let's start with syntax for characters. First, all things you want Excel to know are text must be put inside quotation marks ("). In this instance, I'm asking Excel to look for the [SPACE] character by parsing the string contained in cell A2. If I wanted to parse the string in A2 for the letter B, I'd put FIND("B",A2), for instance.

Find will return the number of characters from the start of the string up to and including the [SPACE] character. If using FIND(" ",A2) for the string Smith, John, Excel will return 7. It counts all characters through Smith,_.

In the B2 formula I posted, you'll notice that FIND is replacing a static data point in the MID function, so we'll move onto MID.

MID(text,start_num,num_chars): Returns the characters from the middle of a text string, given a starting position and length.
In this formula, you will usually reference the text portion of the statement to a cell that contains the text you want to evaluate. The number of characters will be the number of characters you want MID to return after the start number.

If I have the string Smith, John in cell A1 and I want to evaluate the first 3 characters after the space, I need to tell MID where to start in the text. In this case, the space is where I want to start and that is position 7 (we know this from when we used the FIND fucntion above). So, using MID and cell A1 containing Smith, John, we would have the function MID(A1,7,3) which should return [SPACE]Jo. The [SPACE] is included because it's an inclusive formula just like FIND. It starts at and includes the character it starts at. We could write the function as MID("Smith, John",7,3) and arrive at the same answer. We can also write the function using FIND to get MID(A1,FIND(" ",A1),3).

When we use the FIND function, we could also move left or right of that by adding or subtracting some number of characters. In instance of MID in the formula in B2 that I posted, I use the following: MID(A2,FIND(" ",A2)+1,3). This moves the result of the FIND function one character to the right, or 7+1=8. I do this to avoid the function returning the [SPACE] character. Using our example of MID(A1,FIND(" ",A1),3), and changing it to MID(A1,FIND(" ",A1)+1,3), the function will now return "Joh". It's starting at the 8th character (J) and returning 3 characters (J, o, h).

Now we can look at the LEFT function.

LEFT(text,[num_chars]): Returns the specified number of characters from the start of a text string.
Here, I can evaluate a text string and return some n number of characters from the left. If I were to put LEFT("Smith, John",3), then I'd get the value Smi in return. I don't have to use LEFT in the 2nd instance within the formula like I did, I could have just used MID, but I do need it in the first instance in the formula. I did use it so that I could more easily remind myself of what I'm doing with that portion of the formula and I could use it to give myself some flexibilty.

In the formula in B2, we are sending the value of MID to the LEFT formula as the text portion of the statement. I then tell LEFT I want to return only 1 character. So, while MID is giving me 3 characters, LEFT will only give me the first of those 3. Absolutely feel free to use MID(A2,FIND(" ",A2)+1,1) as your formula in place of LEFT(MID(A2,FIND(" ",A2)+1,3),1) because you'll achieve an identical result.

To better explain the advantage of LEFT(MID here, let's say I wanted MID to return the person's entire FirstName and MiddleName. I could reasonably expect to have all that information within an arbitrary number of characters, say 256. I'd write MID as MID(A2,FIND(" ",A2)+1,256) and I should get the person's first and last name. Because I'm building a spreadsheet and I may opt to make adjustments based on how I see data, I could then flex LEFT to return the first 1, 2, 3, 10, 15 or whatever number of characters I choose. It just makes it easier to give myself all the data I could want (from the MID function) and then shorten to what I need (from the LEFT function). So, if I wanted to return the first 3 letters of the data that includes the person's FirstName MiddleName, I can just set the 2nd part of LEFT to 3. I'd then have the formula LEFT(MID(A2,FIND(" ",A2)+1,256),3). If we use our Smith, John example in cell A1, I could put LEFT(MID(A1,FIND(" "),A1)+1,256),3) and it will return Joh. Again, not a necessity here to use LEFT, because we could ask the MID function to do it as follows: MID(A1,FIND(" ",A1)+1,3). I just happen to find it easier as a "reminder" to myself of what I'm doing.

At this point, you probably want to know what the hell I'm doing with LEFT in the first instance in the formula and why I don't use MID. Well, I'll get to that, but let's first explain what TEXT and everyone's favorite, CONCATENATE, are doing.

TEXT(text,format_text): Takes a value in excel and returns it as text regardless of whether or not that original value was text, a number, a symbol, syntax, or whatever. You put something in, it spits it out as text. You get the text part of the formula, but what the hell is format_text. This format_text area is to apply a format code to the value you are going to call text using the formula. Say I want to take the number 3.25 and display it as a fraction but have Excel treat it as text. I'd have to write TEXT(3.25,"# ?/?") This would tell Excel to display any whole number portion of the fracton in addition to the fractional portion. I'd return a result of 3 1/4 as text. If I want to dislay 3.25 entirely as a fraction of 17/4, then I'd have to write either TEXT(3.25,"#?/?") or TEXT(3.25,"?/?"). In my formula I use a double-quote ("") which is the default notation code for general text. Here are some other formats: "$#,##0.00" = currency notation, "0.0%" = percentage notation and so on. Microsoft support has a list of codes/notations here:
https://support.office.com/en-us/art...8-93d29371225c

CONCATENATE(text1,text2,...): Takes several text strings and joins them together. In my formulas, I'm creating two text strings using formulas and join them together with a comma and a space between them. So, I end up with CONCATENATE(text1,", ",text2) where ", " is the comma/space segment. each piece of text is separated in the formula by a comma (text1 then ", " then text2).

So, after stating that, the second instance of TEXT, which contains LEFT(MID(A2... is the formula that find s the person's first initial. I want to join that with their last name separated by a comma and space. This means that the first instance of LEFT is finding their last name.

Recall that LEFT will return all characters, beginning from the left, up to and including whatever character you specify. I wrote the formula as LEFT(A2,FIND(",",A2)-1). I'm trying to get all characters up to the comma, but not inclusive of the comma. FIND(",",A2) returns the number of characters in the string up to and including the comma. In our example of Smith, John I'd then get a return of 6 (Smith,). Since I dont' want the comma, I need to move left by one character which means subtracting 1. FIND(",",A2)-1 will return 5 (Smith). So when I call LEFT, I want it to look at Smith, John and return those 5 characters. I could write LEFT("Smith, John",5) and get a return of Smith. With "Smith, John" in cell A1, I'd equivocally write LEFT(A1,FIND(",",A1)-1) and get the same result of "Smith."

So now that you've learned all this, you say to yourself "kccrow is an idiot, he could have made this all MUCH shorter." And you'd be correct. Why didn't I? Because I usually don't build formulas to be either 1) all inclusive or 2) I will use multiple columns with single formulas and then put them together and then not think about trimming it out to be less extensive, which is EXACTLY what my silly brain did with this at the wee hours of the night when I worked on this.

How simple could this formula get? Very, very simple, in fact. Let's look at our example of Smith, John. If I were to write LEFT(A1,FIND(",",A1)+2) then I'd return the EXACT same answer I did with that huge pile of "wtf" you see inside CONCATENATE but I didn't build it in my brain that way initially (for whatever reason), but I can use this to teach you alot of shit you probably didn't know which is great. So, now that we know we can shorten that B2 formula up to something so short (and the F2 one the same way), lets look at the other two functions.

IFERROR(value,value_if_error): Returns the value of the function you place in the value segment else returns whatever you tell it to do in the value_if_error segment. I choose to return empty text, notated as a double quote (""). You could tell it to say whatever you want, such as "kccrow is brilliant" or 0 or whatever.

IF(logical_test,value_if_true,value_if_false): Returns a value dependent upon whether or not your logical test is true or false. IF(A2="",.... is just asking the formula to do the logical test to check if A2 is empty or contains blank text. I could ask it such things as IF(A2>=0... which is testing if the value in A2 is greater than or equal to 0. It goes on and on and I'll leave you to learn this if you don't know it.

So what am I doing with IF(A2="","",...? I'm asking it to check A2 to see if it's blank, and if it is, then return blank. If it's not return the result of the IFERROR function. If I'm using my Smith, John in A1 example, I should write this as IF(A1="","",IFERROR(LEFT(A1,FIND(",",A1)+2),""). I'm telling the cell to return blank if A1 is blank, blank if the formula LEFT returns an error, and the value of LEFT if its not blank and not an error.

Onto the formula in C2.
I promise my brain didn't skip any beats when I wrote this one and it's about as simple as it gets... just kidding (more later). Here we introduce the MATCH function.

MATCH(lookup_value,lookup_array,match_type): Returns the relative position of an item in an array that matches a specified value in a specified order. Here I used the formula MATCH(B2,F:F,0), which means I'm looking for the value in B2 to see if it matches a value in the array F:F, and I want it to be an Exact Match. Excel states the match types as: 0 = Exact Match, 1 = Greater Than, -1 = Less Than. If the value is an exact match, then MATCH will return the row number of the match in the array F:F. If Excel does not find a match, then MATCH will return an Error which will be displayed as #N/A.

In my formula of IF(A2="","",IF(IFERROR(MATCH(B2,F:F,0),0)>0,"On Roster","Not On Roster")), I return blank if A2 is blank, "Not On Roster" if there is an Error (#N/A), and "On Roster" if there is a match. Now, this formula is LIMITED in it's reliability because I tried to keep it as short and to the point for the needs of the user as I could. The limitation here is that if you enter a number, such as 15, or a name with no comma in A2, then B2 will return "" and C2 will return "On Roster" because there is not a check/balance inherent in the formula to stop such false positives.

I could add a check to ensure that there is a comma entered into the Roster Check column (A) by changing the formula as such:
=IF(IFERROR(FIND(",",A13),0)=0,"Error",IF(A13="","",IF(IFERROR(MATCH(B13,F:F,0),0)>0,"On Roster","Not On Roster"))).
This will tell the Excel to look at the results of FIND and if it returns an Error code (#N/A, #VALUE), return 0, else return the value of find. If it is 0, then the text "Error" will show up in column C. I really don't want to get into how much more complex I'd have to write the formula to check for number entries with a comma, or entries without also at least a first letter after the column. I will, however, point you along. If you want to check for a first letter of a first name existing then you could use IF(A2="","",IFERROR(MID(A2,FIND(" ",A2)+1,1),"Error")). This will give you the letter if it exits or return Error. Incorporating this statement into the formula at the beginning of this paragraph using an AND function would be ideal. All that said, if you have actual specific questions let me know otherwise I'll assume that you're either 1) going to enter names appropriately or 2) create the formula on your own using the tools provided thusfar.

Onto another forumla...

ADDRESS(row_num,col_num,[abs_num],[a1],[sheet_text]): Creates a cell reference as text given specified row and column numbers.
Row number and column number are pretty easy. They are the exact numerical reference to the column or row. For example, column F is column 6 and row 6 is row 6. The special options here, I'm not going to dive into specifcally. I'll just say that abs_num has to do with absolute vs relative references, a1 has to do with reference style types, and sheet_text refers to external worksheet references. You likely will never use any of those and if you need to I'll leave it up to you to research what they do specifically.

The formula I used is as follows: ADDRESS(MATCH($B2,$F:$F,0),5). I'm telling it to send ADDRESS the row reference based on the result of the MATCH function, which we talked about previously. Recall that MATCH returns the row number of the match in the array, so it's a pretty straight forward use of MATCH here. The number 5 is the column number I want to return and here I want it to be E because E contains the person's name on the roster. I could have used a function here instead, as COLUMN(E:E), which would return the number 5 for me. Using this type of function is easier when the number of columns gets large because who wants to count out what column number refers to column PX (which is 440 if you're wondering)? Just use COLUMN(PX:PX) and it will put 440 into the ADDRESS function... easy. So, here I should have stated ADDRESS(MATCH(B2,F:F,0,COLUMN(E:E)). So, now you have better syntax than what I gave you, but it's all relative and still works either way.

Two more functions came into play in the conditional formatting, LEN() and INDEX().

INDEX(array,row_num,[col_num]): Returns the value of a reference to a cell at the intersection of a column and row in a given range.

In my formula I'm looking at INDEX($B:$B,MATCH($F1,$B:$B,0)). Here I'm checking column B (the array) at the row number given by the MATCH function (we've went over this a couple times now so I won't dwell on it) and returning whatever the value in that cell is. For instance, if I check Column B at row 2 in the example given in my previous post, then it should return Anderson, A. What I don't

LEN(text): Returns the number of characters in a text string.

I used the function LEN(INDEX($B:$B,MATCH($F1,$B:$B,0)).
If I ask LEN to evaluate the text string produced by my INDEX function above, it will count the total characters in Anderson, A and return to me the answer of 11. Because I'm using the MATCH function inside of INDEX, LEN will return an Error (#N/A) instead of the string length if a match does not exist. This is why I'm able to use this function for conditional formating. It checks for a match to return to INDEX and if one doesn't exist it will return an error. If MATCH returns a match to INDEX, then INDEX will send a string to LEN which will then return the length of the string. All matches will have a string length greater than 0 and all non-matches will return an error. I use an AND function here to combine LEN>0 and F1<>Short Name because I don't want to highlight the header row, that's simply all that segment is for.

AND is used like an IF statement but combines multiple logical arguments and returns TRUE if all logical arguments are true and FALSE if any logical argument is false. OR is similar in that it combines multiple logical arguments and returns TRUE if any logical argument is true and FALSE if all logical arguments are false. I'll leave it to you to research these simple functions if you aren't educated on them already.

That was long-winded, but I hope it helps you understand everything going on with this. It helped me recognize some oversights for simplicity just typing this out.

[C3HIEF3S]

Originally Posted by kccrow

Two considerations on VLOOKUP vs INDEX(MATCH...

VLOOKUP requires alot of processing power because it evaluates an entire table at once, which is why some workbooks with large data sets seem to take forever to populate a change. VLOOKUP cannot look left of the lookup value. Adding and deleting columns in VLOOKUP also, often, breaks formulas because of the static nature of calling the number of columns to the right to look for. You have to change the formula from VLOOKUP to HLOOKUP to handle vertical and horizontal matching.

INDEX and MATCH have a bit more flexibility and require significantly less processing power because it evaluates a cell reference rather than an entire table. INDEX/MATCH can look anywhere on a sheet: left, right, up, and down. INDEX/MATCH rarely uses static values unless you explicitly tell it to. Most often there is no need to have a static reference value, which means you can add and delete columns and rows with no effect on the outcome, providing you set up the formulas appropriately.

Basically, VLOOKUP is a nice beginner's tool but if you want to do more and get more out of Excel, then learning to use other functions like INDEX, MATCH, LEFT, LEN, ADDRESS, INDIRECT and so forth are going to make your life MUCH easier and more rewarding. Those functions used in conjunction with one another make Excel versatile and allows you to use it like a database. Most beginners struggle with logic though, so keeping the formulas straight and knowing what they are doing is extremely important.

Yes, you could just as easily set up an SQL database with two tables for the names and use an INNER JOIN function to return a list of matches or a LEFT/RIGHT JOIN to return one of the lists entirely and all the matches in the other list. It wouldn't be terrible at all to set up, especially if you can code an HTML UI parsing an INSERT INTO function, but most people that are working with Excel don't also use or know SQL. Even then you're going to have to end up with adding some more complex statements using wildcards and such given the parameters Coach outlined because the data sets don't exactly match. Anyhow, pick one, learn one, and then move on from there. For the vast majority of people, learning Excel will be much more valuable in day-to-day business.

Spot on.
Most people will only ever need Excel and that’s fine. Foundational Excel can get the job done most of the time. Dependent on what your needs are, if one can pick up even basic SQL syntax it will make life SO MUCH easier than resorting to typing out wide Excel formulas. Of course, I’m biased coming from a data science perspective and try to minimize my time in Excel. I’d say I’ve used SQL during 90% of my working days over the last 1.5 years. If one has an opportunity (online courses / YouTube / i.e. at my last gig our BI department was giving SQL lessons) definitely take it, well worth it IMO.

[Coach]

C3HIEF3S and kccrow,

Good stuff gents. If I were to want to learn more about excel, what would be the best practical approach to go in your opinions? Taking a college course? YouTube?

I would imagine it depends on the individual, obviously, but from your experiences, is it better to do online/classes over the YouTube, or the other way around?

[Coach]

Also, isn't there a formula that picks up on words that "sounds" like type of words?

For instance, cat and hat sounds very similar, yes?

[kccrow]

Originally Posted by Coach

C3HIEF3S and kccrow,

Good stuff gents. If I were to want to learn more about excel, what would be the best practical approach to go in your opinions? Taking a college course? YouTube?

I would imagine it depends on the individual, obviously, but from your experiences, is it better to do online/classes over the YouTube, or the other way around?

I think it really depends on how advanced you already are and your preference of learning environment. All of the information you could possibly learn in college courses is available online and much of it for free. Everything you'd learn in a beginner's course in college is available for free through places like GCF and Chandoo. As you advance, most of those sites charge you for the advanced courses, but are usually far cheaper than a college course. Just note that alot of colleges, especially CCs, won't generally allow "testing out" of some classes. For instance, you may not need Excel for Beginners and want to skip to Intermediate. You might be shit out of luck and have to take Beginners first. You'd have to look into it in your area.

I never took a college course in Excel. It's just many years of learning it on my own, asking about things I didn't know or looking it up in books or online. Mr. Excel is a great forum to find things on but you could spend some time looking for the answer you seek.

As for the specific question on words that rhyme, I'm not aware of any inherent formula to Excel that will accomplish that task. You could use a starter word with wildcards in a VLOOKUP. For instance, you want to find all words that contain at... you'd put VLOOKUP("*"&"at"&"*",$B1:$B$40,0) or some effect where the B1:B40 range would contain the words you want to check. You'd end up showing duplicates but could certainly do a formula for unique values in another range.

[C3HIEF3S]

Originally Posted by Coach

C3HIEF3S and kccrow,

Good stuff gents. If I were to want to learn more about excel, what would be the best practical approach to go in your opinions? Taking a college course? YouTube?

I would imagine it depends on the individual, obviously, but from your experiences, is it better to do online/classes over the YouTube, or the other way around?

There's a wide range of (free) community support online that I would tap into first before taking any classes. Since Excel can be used for a pretty broad range of things, if you're just looking for general guides to get you started you really can't go wrong with YouTube. I use YouTube damn near every day to learn, it is one of my most-used learning tools. If my workplace banned YouTube I would throw the biggest ****ing fit and have no worries doing so.

YouTube will be very good for beginning guides and introduction to formulas + concepts. I think first it would be best to identify what you are looking to get out of Excel (in the short-term) to start to kind of narrow down on a couple topics or areas to start out with and then build from there. Definitely take some time to just browse around and find tutorials that work for you and your current skillset. When I am looking for programming / Excel .etc content I always have to sift around to find content that is taught in a way that works for me.

Once you get some foundations down and start to get into formulas, community forums such as StackOverflow will often come up during syntax troubleshooting. For troubleshooting, Google will always be your best friend. Most of the syntax that I know off the top of my head with most-anything I use for analytics wasn't because it was taught to me in a classroom, but because when I was trying to solve a problem I thought to myself "my life would be so much easier if there was a way that I could do X". Don't be afraid to learn as you go, that was one of my struggles starting out. I'd tread water thinking I didn't know something well enough yet to try it out instead of just doing it and learning much faster in the process.

So in a nutshell, find a source to teach you the basics- whether it's YouTube, Google, books,.. whatever works best for you, then find a problem that you want to solve.. something that interests you and just go for it. Give yourself something tangible to get after once you get to a point where you are comfortable with the interface of Excel. For example, my starting point was my love for baseball analytics. Learning the basics of Excel can be a bit of a drag, but learning the basics of Excel while analyzing baseball data? Now that can be fun.
May take a bit to get the hang of, but we all started there as well (and I will always be learning) .

Here are a couple of videos that can be examples of videos to get you started:

[Rudy tossed tigger's salad]

God dammit, I feel like such a ****ing moron. This seems like it should be a basic ****ing task. How do I do this in google sheets?

[scho63]

Originally Posted by Rudy tossed tigger's salad

God dammit, I feel like such a ****ing moron. This seems like it should be a basic ****ing task. How do I do this in google sheets?

Google sheets DOES NOT do everything that Excel does. It is also a little complicated at times to do complex formulas or transactions.